GDT finally works

kernel/arch/x86_64/link.ld

@@ -0,0 +1,72 @@
+/* Tell the linker that we want an x86_64 ELF64 output file */
+OUTPUT_FORMAT(elf64-x86-64)
+OUTPUT_ARCH(i386:x86-64)
+
+/* We want the symbol _start to be our entry point */
+ENTRY(kmain)
+
+/* Define the program headers we want so the bootloader gives us the right */
+/* MMU permissions */
+PHDRS
+{
+    text    PT_LOAD    FLAGS((1 << 0) | (1 << 2)) ; /* Execute + Read */
+    rodata  PT_LOAD    FLAGS((1 << 2)) ;            /* Read only */
+    data    PT_LOAD    FLAGS((1 << 1) | (1 << 2)) ; /* Write + Read */
+    dynamic PT_DYNAMIC FLAGS((1 << 1) | (1 << 2)) ; /* Dynamic PHDR for relocations */
+}
+
+SECTIONS
+{
+    /* We wanna be placed in the topmost 2GiB of the address space, for optimisations */
+    /* and because that is what the Limine spec mandates. */
+    /* Any address in this region will do, but often 0xffffffff80000000 is chosen as */
+    /* that is the beginning of the region. */
+    . = 0xffffffff80000000;
+
+    kernel_start = .;
+    kernel_text_start = .;
+    .text : {
+        *(.text .text.*)
+    } :text
+    kernel_text_end = .;
+
+    /* Move to the next memory page for .rodata */
+    . += CONSTANT(MAXPAGESIZE);
+
+    kernel_rodata_start = .;
+    .rodata : {
+        *(.rodata .rodata.*)
+    } :rodata
+    kernel_rodata_end = .;
+
+    /* Move to the next memory page for .data */
+    . += CONSTANT(MAXPAGESIZE);
+
+    kernel_data_start = .;
+    .data : {
+        *(.data .data.*)
+    } :data
+
+    /* Dynamic section for relocations, both in its own PHDR and inside data PHDR */
+    .dynamic : {
+        *(.dynamic)
+    } :data :dynamic
+
+    /* NOTE: .bss needs to be the last thing mapped to :data, otherwise lots of */
+    /* unnecessary zeros will be written to the binary. */
+    /* If you need, for example, .init_array and .fini_array, those should be placed */
+    /* above this. */
+    .bss : {
+        *(.bss .bss.*)
+        *(COMMON)
+    } :data
+    kernel_data_end = .;
+
+    /* Discard .note.* and .eh_frame since they may cause issues on some hosts. */
+    /DISCARD/ : {
+        *(.eh_frame)
+        *(.note .note.*)
+    }
+
+    kernel_end = .;
+}

kernel/arch/x86_64/x86_64.mk

@@ -0,0 +1,22 @@
+CC := x86_64-elf-gcc
+LD := x86_64-elf-ld
+
+CFLAGS += -m64 \
+					-fPIE \
+					-mno-80387 \
+					-mno-mmx \
+					-mno-sse \
+					-nostartfiles \
+					-nostdlib \
+					-mno-sse2 \
+					-mno-red-zone \
+					-fno-stack-protector \
+					-fno-stack-check \
+					-fno-lto
+
+LDFLAGS += -m elf_x86_64 \
+					-pie \
+					--no-dynamic-linker \
+					-z text \
+					-z max-page-size=0x1000
+